mirror of
https://github.com/X11Libre/xf86-video-intel.git
synced 2026-04-14 10:54:23 +00:00
90576f95f3
Added m4 check for XORG_DRIVER_CHECK_EXT macro definition. Updated m4 fatal messages to give better hint on how to resolve error when xorg macros are missing. Previously, configure would continue in spite of the missing macros and the build would fail for syntax errors.
166 lines
6.0 KiB
Plaintext
166 lines
6.0 KiB
Plaintext
# Copyright 2005 Adam Jackson.
|
|
#
|
|
# Permission is hereby granted, free of charge, to any person obtaining a
|
|
# copy of this software and associated documentation files (the "Software"),
|
|
# to deal in the Software without restriction, including without limitation
|
|
# on the rights to use, copy, modify, merge, publish, distribute, sub
|
|
# license, and/or sell copies of the Software, and to permit persons to whom
|
|
# the Software is furnished to do so, subject to the following conditions:
|
|
#
|
|
# The above copyright notice and this permission notice (including the next
|
|
# paragraph) shall be included in all copies or substantial portions of the
|
|
# Software.
|
|
#
|
|
# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
|
|
# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
|
|
# FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT. IN NO EVENT SHALL
|
|
# ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
|
|
# IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
|
|
# CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
|
|
#
|
|
# Process this file with autoconf to produce a configure script
|
|
|
|
# Initialize Autoconf
|
|
AC_PREREQ([2.60])
|
|
AC_INIT([xf86-video-intel],
|
|
[2.13.902],
|
|
[https://bugs.freedesktop.org/enter_bug.cgi?product=xorg],
|
|
[xf86-video-intel])
|
|
AC_CONFIG_SRCDIR([Makefile.am])
|
|
AC_CONFIG_HEADERS([config.h])
|
|
AC_CONFIG_AUX_DIR(.)
|
|
|
|
# Initialize Automake
|
|
AM_INIT_AUTOMAKE([foreign dist-bzip2])
|
|
AM_MAINTAINER_MODE
|
|
|
|
# Require X.Org macros 1.8 or later for MAN_SUBSTS set by XORG_MANPAGE_SECTIONS
|
|
m4_ifndef([XORG_MACROS_VERSION],
|
|
[m4_fatal([must install xorg-macros 1.8 or later before running autoconf/autogen.
|
|
Try "apt-get install xutils-dev" or "yum install xorg-x11-util-macros"])])
|
|
XORG_MACROS_VERSION(1.8)
|
|
XORG_DEFAULT_OPTIONS
|
|
|
|
# Require X.Org server macros (i.e. XORG_DRIVER_CHECK_EXT) to check for required modules
|
|
m4_ifndef([XORG_DRIVER_CHECK_EXT],
|
|
[m4_fatal([must install xorg-server macros before running autoconf/autogen.
|
|
Try "apt-get install xserver-xorg-dev" or "yum install xorg-x11-server-devel"])])
|
|
|
|
# Initialize libtool
|
|
AC_DISABLE_STATIC
|
|
AC_PROG_LIBTOOL
|
|
|
|
PKG_CHECK_MODULES(GEN4ASM, [intel-gen4asm >= 1.1], [gen4asm=yes], [gen4asm=no])
|
|
AM_CONDITIONAL(HAVE_GEN4ASM, test x$gen4asm = xyes)
|
|
|
|
PKG_CHECK_MODULES(UDEV, [libudev], [udev=yes], [udev=no])
|
|
if test x"$udev" = xyes; then
|
|
AC_DEFINE(HAVE_UDEV,1,[Enable udev-based monitor hotplug detection])
|
|
fi
|
|
|
|
AH_TOP([#include "xorg-server.h"])
|
|
|
|
# Define a configure option for an alternate module directory
|
|
AC_ARG_WITH(xorg-module-dir,
|
|
AS_HELP_STRING([--with-xorg-module-dir=DIR],
|
|
[Default xorg module directory [[default=$libdir/xorg/modules]]]),
|
|
[moduledir="$withval"],
|
|
[moduledir="$libdir/xorg/modules"])
|
|
|
|
AC_ARG_ENABLE(dri, AS_HELP_STRING([--disable-dri],
|
|
[Disable DRI support [[default=auto]]]),
|
|
[DRI="$enableval"],
|
|
[DRI=auto])
|
|
|
|
AC_ARG_ENABLE(xvmc, AS_HELP_STRING([--disable-xvmc],
|
|
[Disable XvMC support [[default=yes]]]),
|
|
[XVMC="$enableval"],
|
|
[XVMC=yes])
|
|
|
|
AC_ARG_ENABLE(kms-only, AS_HELP_STRING([--enable-kms-only],
|
|
[Assume KMS support [[default=no]]]),
|
|
[KMS_ONLY="$enableval"],
|
|
[KMS_ONLY=no])
|
|
|
|
# Store the list of server defined optional extensions in REQUIRED_MODULES
|
|
XORG_DRIVER_CHECK_EXT(RANDR, randrproto)
|
|
XORG_DRIVER_CHECK_EXT(RENDER, renderproto)
|
|
XORG_DRIVER_CHECK_EXT(XF86DRI, xextproto x11)
|
|
XORG_DRIVER_CHECK_EXT(DPMSExtension, xextproto)
|
|
|
|
# Obtain compiler/linker options for the driver dependencies
|
|
PKG_CHECK_MODULES(XORG, [xorg-server >= 1.6 xproto fontsproto $REQUIRED_MODULES])
|
|
PKG_CHECK_MODULES(DRM, [libdrm >= 2.4.23])
|
|
PKG_CHECK_MODULES(PCIACCESS, [pciaccess >= 0.10])
|
|
|
|
sdkdir=`$PKG_CONFIG --variable=sdkdir xorg-server`
|
|
|
|
save_CFLAGS="$CFLAGS"
|
|
CFLAGS="$XORG_CFLAGS $DRI_CFLAGS $DRM_CFLAGS"
|
|
CPPFLAGS="$XORG_CFLAGS $DRI_CFLAGS $DRM_CFLAGS"
|
|
AC_MSG_CHECKING([whether to include DRI support])
|
|
if test x$DRI != xno; then
|
|
AC_CHECK_FILE([${sdkdir}/dri.h],
|
|
[have_dri_h="yes"], [have_dri_h="no"])
|
|
AC_CHECK_FILE([${sdkdir}/sarea.h],
|
|
[have_sarea_h="yes"], [have_sarea_h="no"])
|
|
AC_CHECK_FILE([${sdkdir}/dristruct.h],
|
|
[have_dristruct_h="yes"], [have_dristruct_h="no"])
|
|
fi
|
|
AC_MSG_CHECKING([whether to include DRI support])
|
|
if test x$DRI = xauto; then
|
|
if test "$have_dri_h" = yes -a \
|
|
"$have_sarea_h" = yes -a \
|
|
"$have_dristruct_h" = yes; then
|
|
DRI="yes"
|
|
else
|
|
DRI="no"
|
|
fi
|
|
fi
|
|
AC_MSG_RESULT([$DRI])
|
|
CFLAGS="$save_CFLAGS $DEBUGFLAGS"
|
|
|
|
AM_CONDITIONAL(DRI, test x$DRI = xyes)
|
|
if test "$DRI" = yes; then
|
|
PKG_CHECK_MODULES(DRI, [xf86driproto])
|
|
AC_DEFINE(XF86DRI,1,[Enable DRI driver support])
|
|
AC_DEFINE(XF86DRI_DEVEL,1,[Enable developmental DRI driver support])
|
|
fi
|
|
|
|
if test "$XVMC" = yes; then
|
|
PKG_CHECK_MODULES(XVMCLIB,
|
|
[xvmc xext xfixes dri2proto x11-xcb xcb-dri2 xcb-aux],
|
|
[XVMC=yes], [XVMC=no])
|
|
fi
|
|
AC_MSG_CHECKING([whether to include XvMC support])
|
|
AC_MSG_RESULT([$XVMC])
|
|
AM_CONDITIONAL(XVMC, test x$XVMC = xyes)
|
|
if test "$XVMC" = yes; then
|
|
AC_DEFINE(ENABLE_XVMC,1,[Enable XvMC support])
|
|
fi
|
|
|
|
AM_CONDITIONAL(KMS_ONLY, test x$KMS_ONLY = xyes)
|
|
if test "$KMS_ONLY" = yes; then
|
|
AC_DEFINE(KMS_ONLY,1,[Assume KMS support])
|
|
fi
|
|
|
|
DRIVER_NAME=intel
|
|
AC_SUBST([DRIVER_NAME])
|
|
AC_SUBST([moduledir])
|
|
|
|
AC_CONFIG_FILES([
|
|
Makefile
|
|
uxa/Makefile
|
|
src/Makefile
|
|
src/xvmc/Makefile
|
|
src/xvmc/shader/Makefile
|
|
src/xvmc/shader/mc/Makefile
|
|
src/xvmc/shader/vld/Makefile
|
|
src/legacy/Makefile
|
|
src/legacy/i810/Makefile
|
|
src/legacy/i810/xvmc/Makefile
|
|
man/Makefile
|
|
src/render_program/Makefile
|
|
])
|
|
AC_OUTPUT
|