mirror of
https://github.com/X11Libre/xf86-video-geode.git
synced 2026-03-24 01:24:52 +00:00
ac99bf2c5c
For gcc compiler only at the moment. The configuration reports if support is found or not, e.g.: checking if gcc supports the -m32 Intel/AMD option... yes The configuration C test relies on #include unistd.h which includes features.h which includes gnu/stubs.h which includes gnu/stubs-32.h which is missing on 64 bit system without the 32 bit library support. Tested on x86_64 AMD64 CPU with/without libc6-dev-i386 which provides 32 bit support. Remains to be tested on Geode and FreeBSD 32/64 bit. The configuration does not attempt to decide if building should proceed or be aborted. If no 32 bit support then the build will die in the assembly code as it always did before. The variable M32_CFLAGS provides the flag for the makefiles. The variable names and organization is subject to change. Signed-off-by: Gaetan Nadon <memsize@videotron.ca>
149 lines
4.6 KiB
Plaintext
149 lines
4.6 KiB
Plaintext
# Copyright 2005 Adam Jackson.
|
|
#
|
|
# Permission is hereby granted, free of charge, to any person obtaining a
|
|
# copy of this software and associated documentation files (the "Software"),
|
|
# to deal in the Software without restriction, including without limitation
|
|
# on the rights to use, copy, modify, merge, publish, distribute, sub
|
|
# license, and/or sell copies of the Software, and to permit persons to whom
|
|
# the Software is furnished to do so, subject to the following conditions:
|
|
#
|
|
# The above copyright notice and this permission notice (including the next
|
|
# paragraph) shall be included in all copies or substantial portions of the
|
|
# Software.
|
|
#
|
|
# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
|
|
# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
|
|
# FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT. IN NO EVENT SHALL
|
|
# ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
|
|
# IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
|
|
# CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
|
|
#
|
|
# Process this file with autoconf to produce a configure script
|
|
|
|
AC_PREREQ(2.59)
|
|
AC_INIT([xf86-video-geode],
|
|
[2.11.12],
|
|
[https://bugs.freedesktop.org/enter_bug.cgi?product=xorg&component=Driver%2Fgeode],
|
|
[xf86-video-geode],
|
|
[http://www.x.org/wiki/GeodeDriver])
|
|
|
|
AC_CONFIG_SRCDIR([Makefile.am])
|
|
AM_CONFIG_HEADER([config.h])
|
|
AC_CONFIG_AUX_DIR(.)
|
|
|
|
# Require xorg-macros: XORG_DEFAULT_OPTIONS
|
|
m4_ifndef([XORG_MACROS_VERSION],
|
|
[m4_fatal([must install xorg-macros 1.4 or later before running autoconf/autogen])])
|
|
XORG_MACROS_VERSION(1.4)
|
|
XORG_DEFAULT_OPTIONS
|
|
|
|
AM_INIT_AUTOMAKE([foreign dist-bzip2])
|
|
|
|
AM_MAINTAINER_MODE
|
|
|
|
# Checks for programs.
|
|
AC_DISABLE_STATIC
|
|
AC_PROG_LIBTOOL
|
|
AC_PROG_CC
|
|
|
|
AH_TOP([#include "xorg-server.h"])
|
|
|
|
AC_ARG_WITH(xorg-module-dir,
|
|
AC_HELP_STRING([--with-xorg-module-dir=DIR],
|
|
[Default xorg module directory [[default=$libdir/xorg/modules]]]),
|
|
[moduledir="$withval"],
|
|
[moduledir="$libdir/xorg/modules"])
|
|
|
|
AC_ARG_ENABLE(geodegx-panel,
|
|
AC_HELP_STRING([--disable-geodegx-panel],
|
|
[Disable support for flatpanels with the Geode GX]),
|
|
[ ],
|
|
[ AMD_CFLAGS="-DPNL_SUP $AMD_CFLAGS" ])
|
|
|
|
# Define a configure option to enable/disable ztv
|
|
AC_ARG_ENABLE(ztv,
|
|
AS_HELP_STRING([--enable-ztv],
|
|
[Enable Video For Linux based ZTV driver (default: auto-detected)]),
|
|
[ztv=$enableval],
|
|
[ztv=auto])
|
|
|
|
# Check for Video4Linux Version 2 (V4L2) availability
|
|
AC_CHECK_HEADERS([linux/videodev2.h],[v4l2=yes],[v4l2=no])
|
|
if test "x$ztv" != "xno" ; then
|
|
if test "x$v4l2" = "xno" ; then
|
|
if test "x$ztv" = "xyes" ; then
|
|
# User really wants ztv but V4L2 is not found
|
|
AC_MSG_ERROR([ZTV driver requested, but videodev2.h not found.])
|
|
fi
|
|
else
|
|
BUILD_ZTV=yes
|
|
fi
|
|
fi
|
|
AM_CONDITIONAL(BUILD_ZTV, [test "x$BUILD_ZTV" = xyes])
|
|
|
|
# Check if GCC supports compiling in 32 bit mode for 64 bit computers
|
|
case $host_cpu in
|
|
x86_64*|amd64*)
|
|
if test "x$GCC" = xyes ; then
|
|
SAVE_CFLAGS="$CFLAGS"
|
|
CFLAGS="$CFLAGS -m32"
|
|
AC_MSG_CHECKING([if $CC supports the -m32 Intel/AMD option])
|
|
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
|
|
#include <unistd.h>
|
|
int
|
|
main ()
|
|
{
|
|
;
|
|
return 0;
|
|
}]])],
|
|
[m32_support=yes; M32_CFLAGS=-m32],
|
|
[m32_support=no])
|
|
AC_MSG_RESULT([$m32_support])
|
|
CFLAGS="$SAVE_CFLAGS"
|
|
fi
|
|
;;
|
|
esac
|
|
AC_SUBST([M32_CFLAGS])
|
|
|
|
# Checks for extensions
|
|
XORG_DRIVER_CHECK_EXT(RANDR, randrproto)
|
|
XORG_DRIVER_CHECK_EXT(RENDER, renderproto)
|
|
XORG_DRIVER_CHECK_EXT(XV, videoproto)
|
|
XORG_DRIVER_CHECK_EXT(DPMSExtension, xextproto)
|
|
|
|
# Checks for pkg-config packages
|
|
PKG_CHECK_MODULES(XORG, [xorg-server xproto fontsproto $REQUIRED_MODULES])
|
|
PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
|
|
HAVE_XEXTPROTO_71="yes"; AC_DEFINE(HAVE_XEXTPROTO_71, 1, [xextproto 7.1 available]),
|
|
HAVE_XEXTPROTO_71="no")
|
|
AM_CONDITIONAL(HAVE_XEXTPROTO_71, [ test "$HAVE_XEXTPROTO_71" = "yes" ])
|
|
|
|
# Checks for libraries.
|
|
SAVE_CPPFLAGS="$CPPFLAGS"
|
|
CPPFLAGS="$CPPFLAGS $XORG_CFLAGS"
|
|
AC_CHECK_DECL(XSERVER_LIBPCIACCESS,
|
|
[XSERVER_LIBPCIACCESS=yes],[XSERVER_LIBPCIACCESS=no],
|
|
[#include "xorg-server.h"])
|
|
CPPFLAGS="$SAVE_CPPFLAGS"
|
|
|
|
# Checks for header files.
|
|
AC_HEADER_STDC
|
|
|
|
if test "x$XSERVER_LIBPCIACCESS" = xyes; then
|
|
PKG_CHECK_MODULES([PCIACCESS], [pciaccess >= 0.8.0])
|
|
XORG_CFLAGS="$XORG_CFLAGS $PCIACCESS_CFLAGS"
|
|
fi
|
|
|
|
AC_SUBST([XORG_CFLAGS])
|
|
AC_SUBST([moduledir])
|
|
AC_SUBST([AMD_CFLAGS])
|
|
|
|
DRIVER_NAME=geode
|
|
AC_SUBST([DRIVER_NAME])
|
|
|
|
AC_OUTPUT([
|
|
Makefile
|
|
src/Makefile
|
|
ztv/Makefile
|
|
])
|