* Added plugin support

* Improved Filer (LocalFiler)
* Supports Explicit SSL/TLS with OpenSSL/Crypto
* Fixed most of the bugs that drove me nuts.
* Properly handled socket closes
* Improved socket cleanup
* Buffered file downloads
* Lots 'o errors!

I did it again! I made a single commit with everything!

cmake/FindPAM.cmake

@@ -0,0 +1,37 @@
+# Find PAM headers
+find_path(PAM_INCLUDE_DIR
+    NAMES security/pam_appl.h
+    PATHS /usr/include
+          /usr/local/include
+)
+
+# Find PAM library
+find_library(PAM_LIBRARY
+    NAMES pam
+    PATHS /usr/lib
+          /usr/lib64
+          /usr/local/lib
+          /usr/local/lib64
+)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(PAM
+    REQUIRED_VARS
+        PAM_LIBRARY
+        PAM_INCLUDE_DIR
+)
+
+if(PAM_FOUND)
+    set(PAM_LIBRARIES ${PAM_LIBRARY})
+    set(PAM_INCLUDE_DIRS ${PAM_INCLUDE_DIR})
+    
+    if(NOT TARGET PAM::PAM)
+        add_library(PAM::PAM UNKNOWN IMPORTED)
+        set_target_properties(PAM::PAM PROPERTIES
+            IMPORTED_LOCATION "${PAM_LIBRARY}"
+            INTERFACE_INCLUDE_DIRECTORIES "${PAM_INCLUDE_DIR}"
+        )
+    endif()
+endif()
+
+mark_as_advanced(PAM_INCLUDE_DIR PAM_LIBRARY)